↑  ←  Описание функции

_GUICtrlComboBox_Create

Создаёт элемент ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_Create($hWnd, $sText, $iX, $iY [, $iWidth = 100 [, $iHeight = 120 [, $iStyle = 0x00200042 [, $iExStyle = 0x00000000]]]])

Параметры

$hWnd Дескриптор родительского окна или окна владельца
$sText Разделённая строка для добавления в ComboBox
$iX Координата левого края
$iY Координата верхнего края
$iWidth [необязательный] Ширина элемента
$iHeight [необязательный] Высота элемента
$iStyle [необязательный] Стиль элемента:
    $CBS_AUTOHSCROLL - Автоматически сдвигает текст в поле ввода, когда пользователь вводит символ в конце строки у правого края элемента.
    $CBS_DISABLENOSCROLL - Отображает вертикальную полосу прокрутки, даже если список содержит недостаточное количество элементов.
    $CBS_DROPDOWN - Подобен $CBS_SIMPLE, но не отображается список, пока пользователь не нажмёт элемент справа от поля ввода для раскрытия списка.
    $CBS_DROPDOWNLIST - Подобен $CBS_DROPDOWN, но поле ввода недоступно для редактирования, и только отображает текущий выбор в списке.
    $CBS_LOWERCASE - Преобразует в нижний регистр весь текст в поле ввода и в списке.
    $CBS_NOINTEGRALHEIGHT - Указывает, что размер ComboBox - точный размер указанный приложением при его создании. Без этого стиля элемент подстраивает высоту кратно высоте строк, не допуская частичного отображения строки.
    $CBS_OEMCONVERT - Преобразует текст, введенный в раскрывающийся список из набора символов Windows в набор символов OEM (DOS), а затем обратно в набор Windows
    $CBS_OWNERDRAWFIXED - Определяет, что владелец списка ответственен за прорисовку его содержания, и что пункты в списке равной высоты.
    $CBS_OWNERDRAWVARIABLE - Определяет, что владелец списка ответственен за прорисовку его содержания, и что пункты в списке переменной высоты.
    $CBS_SIMPLE - Список отображается всегда.
    $CBS_SORT - Автоматически сортирует строки добавляемые в список
    $CBS_UPPERCASE - Преобразует в верхний регистр весь текст в поле ввода и в списке.
    По умолчанию: $CBS_DROPDOWN, $CBS_AUTOHSCROLL, $WS_VSCROLL     Принудительно : $WS_CHILD, $WS_TABSTOP, $WS_VISIBLE
$iExStyle [необязательный] Расширенный стиль элемента. Соответствует стандартным константам $WS_EX_.

Возвращаемое значение

Успех:Возвращает дескриптор элемента Listbox
Ошибка:Возвращает 0

Примечания

Эта функция предназначена для опытных пользователей и для изучения того, как элемент работает.

См. также

_GUICtrlComboBox_Destroy

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $hCombo

_Main()

Func _Main()
    Local $hGUI

    ; Создаёт GUI
    $hGUI = GUICreate("(UDF) Создаёт ComboBox", 400, 296)
    $hCombo = _GUICtrlComboBox_Create($hGUI, "", 2, 2, 396, 296)
    GUISetState()

    ; Добавляет файлы
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, "", $DDL_DRIVES, False)
    _GUICtrlComboBox_EndUpdate($hCombo)

    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg
    Local $hWndFrom, $iIDFrom, $iCode
    $hWndFrom = $ilParam
    $iIDFrom = BitAND($iwParam, 0xFFFF) ; младшее слово
    $iCode = BitShift($iwParam, 16) ; старшее слово
    Switch $hWndFrom
        Case $hCombo
            Switch $iCode
                Case $CBN_CLOSEUP ; Высылается, когда выпадающий список был закрыт
                    _DebugPrint("$CBN_CLOSEUP" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $CBN_DBLCLK ; Высылается, когда пользователь сделал двойной клик на строке в списке ComboBox
                    _DebugPrint("$CBN_DBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $CBN_DROPDOWN ; Высылается, когда выпадающий список ComboBox'а был развёрнут
                    _DebugPrint("$CBN_DROPDOWN" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $CBN_EDITCHANGE ; Высылается после того, как пользователь выполнил действие, которое может изменить текст в поле ввода ComboBox'а
                    _DebugPrint("$CBN_EDITCHANGE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $CBN_EDITUPDATE ; Высылается, когда поле ввода ComboBox'а отображает изменённый текст
                    _DebugPrint("$CBN_EDITUPDATE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $CBN_ERRSPACE ; Высылается, когда ComboBox не может выделить достаточно памяти для выполнения определённого запроса
                    _DebugPrint("$CBN_ERRSPACE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $CBN_KILLFOCUS ; Высылается, когда ComboBox теряет фокус
                    _DebugPrint("$CBN_KILLFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $CBN_SELCHANGE ; Высылается, когда пользователь изменяет текущий выбор из списка ComboBox
                    _DebugPrint("$CBN_SELCHANGE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $CBN_SELENDCANCEL ; Высылается, когда пользователь раскрывает список, но ничего не выбирает, кликая другой элемент окна или просто закрывая список.
                    _DebugPrint("$CBN_SELENDCANCEL" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $CBN_SELENDOK ; Высылается, когда пользователь выбирает пункт списка, или выбирает пункт и затем закрывает список
                    _DebugPrint("$CBN_SELENDOK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $CBN_SETFOCUS ; Высылается, когда ComboBox получил фокус
                    _DebugPrint("$CBN_SETFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func _DebugPrint($s_text, $line = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @LF & _
            "+======================================================" & @LF & _
            "-->Строка(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
            "+======================================================" & @LF)
EndFunc   ;==>_DebugPrint