WinGetState
Получает состояние указанного окна.
WinGetState ( "title" [, "text" ] )
Параметры
| title | Заголовок/дескриптор/класс окна. См. заголовки и текст окон (расширенные). |
| text |
[необязательный] Текст окна. |
Возвращаемое значение
| Успех: | Возвращает значение, указывающее состояние окна. Используйте BitAND(), чтобы проверить содержит ли сумма параметров интересующую вас составляющую: |
| 1 = существует | |
| 2 = отображается | |
| 4 = доступно | |
| 8 = активно | |
| 16 = свёрнуто | |
| 32 = развёрнуто | |
| Ошибка: | Возвращает 0 и устанавливает @error равным 1, если указанное окно не найдено. |
См. также
WinSetState, BitAND, WinGetPosПример
; WinSetState("[ACTIVE]", "", @SW_MAXIMIZE)
; Извлекаем состояние активного окна
$iState = WinGetState("[ACTIVE]", "")
$sText = ''
; Проверка, наличия указанных параметров состояния окна?
If BitAND($iState, 1) Then
$sText &= 'существует' & @LF
Else
MsgBox(4096, "Сообщение", 'ОКНО НЕ СУЩЕСТВУЕТ')
Exit
EndIf
If BitAND($iState, 2) Then
$sText &= 'не скрыто' & @LF ; @SW_SHOW
Else
$sText &= 'скрыто' & @LF ; @SW_HIDE
EndIf
If BitAND($iState, 4) Then
$sText &= 'доступно' & @LF ; @SW_ENABLE
Else
$sText &= 'не доступно' & @LF ; @SW_DISABLE
EndIf
If BitAND($iState, 8) Then
$sText &= 'активно' & @LF
Else
$sText &= 'не активно' & @LF
EndIf
If BitAND($iState, 16) Then
$sText &= 'свёрнуто' & @LF ; @SW_MINIMIZE
Else
$sText &= 'не свёрнуто' & @LF ; @SW_RESTORE
EndIf
If BitAND($iState, 32) Then
$sText &= 'развёрнуто на весь экран' & @LF ; @SW_MAXIMIZE
Else
$sText &= 'не развёрнуто на весь экран' & @LF ; @SW_RESTORE
EndIf
MsgBox(4096, "Сообщение", $sText)