↑  ←  Описание функции


UBound

Возвращает размер массива.

UBound ( Array [, Dimension = 1 ] )

Параметры

Array Массив.
Dimension [необязательный] Указывает, информацию о каком измерении многомерного массива необходимо получить. По умолчанию равно 1, что означает первое измерение. Если этот параметр равен 0, функция возвращает число измерений массива.

Возвращаемое значение

Успех:Возвращает размер измерения массива.
Ошибка:Возвращает 0 и устанавливает значение @error:
1 = Переданная переменная не является массивом.
2 = Указано неверное измерение массива.

Примечания

Помните, что значение, возвращаемое функций UBound(), на 1 больше, чем номер последнего элемента в измерении массива.

См. также

Global/Local, ReDim, IsArray

Пример

#include <Array.au3> ; для _ArrayDisplay.

Local $aArray[10][5]
Local $iRows = UBound($aArray, 1) ; Обще количество строк. В данном примере 10.
Local $iCols = UBound($aArray, 2) ; Обще количество колонок. В данном примере 5.
Local $iDimension = UBound($aArray, 0) ; Размерность массива, к примеру 1/2/3 -мерный.

MsgBox(4096, "", "Массив " & $iDimension & '-мерный' & @CRLF & _
        'с количеством строк ' & $iRows & @CRLF & _
        'с количеством колонок: ' & $iCols)

; Заполнение массива данными
For $i = 0 To $iRows - 1
    For $j = 0 To $iCols - 1
        $aArray[$i][$j] = "стр: " & $i & ", кол: " & $j
    Next
Next

; Просмотр массива
_ArrayDisplay($aArray, 'С указанием строки и колонки в ячейках')