↑  ←  Описание функции


TrayCreateMenu

Создаёт элемент меню для иконки в трее.

TrayCreateMenu ( "sub/menutext" [, menuID = -1 [, menuentry = -1 ]] )

Параметры

sub/menutext Текст меню/подменю.
menuID [необязательный] Если указано, позволяет создать вложенное меню в указанном подменю. Если указан -1, то создаётся в меню первого уровня (в корневом).
menuentry [необязательный] Позволяет установить очерёдность элемента в меню. Отсчёт начинается с 0.

Возвращаемое значение

Успех:Возвращает идентификатор (controlID) нового элемента меню.
Ошибка:Возвращает 0.

См. также

TrayItemSetState, TrayItemSetText, TrayGetMsg, TrayItemDelete

Пример

#NoTrayIcon

Opt("TrayMenuMode", 1 + 2) ; Не отображать в трее пункты меню по умолчанию (Script Paused/Exit) и не отмечать галочками при выборе.

$iSettings = TrayCreateMenu("Настройки") ; Создаёт меню трея и подменю с двумя пунктами.
$iDisplay = TrayCreateItem("Монитор", $iSettings)
$iPrinter = TrayCreateItem("Принтер", $iSettings)
TrayCreateItem("") ; Создаёт разделитель

$iAbout = TrayCreateItem("О программе")
TrayCreateItem("") ; Создаёт разделитель

$iExit = TrayCreateItem("Выход")

TraySetState(1) ; Показывает меню трея

While 1
    Switch TrayGetMsg()
        Case $iAbout
            MsgBox(4096, "", "Пример меню в трее." & @CRLF & @CRLF & _
                    "Версия AutoIt: " & @AutoItVersion & @CRLF & _
                    "Путь установки: " & StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", 0, -1) - 1))

        Case $iDisplay, $iPrinter
            MsgBox(4096, "", "Был выбран вложенный пункт в меню трея.")

        Case $iExit ; Выход
            ExitLoop
    EndSwitch
WEnd