↑  ←  Описание функции


ToolTip

Создаёт всплывающую подсказку в любом месте экрана.

ToolTip ( "text" [, x [, y [, "title" [, icon = 0 [, options ]]]]] )

Параметры

text Текст всплывающей подсказки. Пустая строка означает, что отображаемая всплывающая подсказка будет очищена.
x [необязательный] Координата всплывающей подсказки по x. По умолчанию используется текущая координата курсора мыши.
y [необязательный] Координата всплывающей подсказки по y. По умолчанию используется текущая координата курсора мыши.
title [необязательный] Заголовок всплывающей подсказки (Требует IE5+)
icon [необязательный] Иконка, отображаемая рядом с заголовком: требует указания параметра title.
    0 - (по умолчанию) Без иконки
    1 - Иконка "Информация"
    2 - Иконка "Предупреждение"
    3 - Иконка "Ошибка"
options [необязательный] Дополнительные опции (сложите необходимые значения):
    1 = отобразить, как овальная (Balloon Tip) (Требует IE5+)
    2 = центрировать подсказку по координатам x,y (по умолчанию это координаты левого верхнего угла подсказки).
    4 = принудительно отображать подсказку полностью, независимо от указанных координат. Если используется несколько мониторов, подсказка будет "прилипать" к ближайшему монитору.

Возвращаемое значение

Успех:Возвращает 1.
Ошибка:Возвращает 0, если длина заголовка превышает 99 символов.

Примечания

Чтобы пропустить указание необязательного параметра, оставьте вместо него значение по умолчанию, равное Default.

Всплывающая подсказка будет отображаться до завершения скрипта или до вызова ToolTip("").
Можно использовать символы @CR или @LF для создания многострочной всплывающей подсказки.

Если используются опции 1 (овальная, Balloon Tip) и 2 (центрирование по координатам) одновременно, то треугольная сноска будет находиться над центром всплывающей подсказки в указанных координатах.

См. также

TrayTip, MsgBox, SplashTextOn

Пример

; Это создаёт подсказки в левом верхнем углу экрана
ToolTip("Это подсказка", 0, 0)
Sleep(1000) ; Sleep чтобы дать ToolTip некоторое время отображаться

; Пример вывода данных в ходе выполнения задачи
For $i = 0 To 3
    ToolTip('Таймер: ' & $i & ' сек' & @CRLF & 'изменение иконки', Default, Default, 'Статистика', $i, 4)
    Sleep(1000)
Next

; Изменение стиля
For $i = 1 To 4
    ToolTip('Таймер: ' & $i + 3 & ' сек' & @CRLF & 'изменение стиля', Default, Default, 'Статистика', 1, $i)
    Sleep(1000)
Next

; Пример использования другой иконки
#include <WinAPI.au3>

; Получает дескриптор иконки
$hIcon = _WinAPI_LoadShell32Icon(15) ; также _WinAPI_ExtractIconEx
ToolTip('Можно использовать' & @CRLF & 'дескриптор иконки', Default, Default, 'Своя иконка', $hIcon, 4)
Sleep(1500)