↑  ←  Описание функции


GUICtrlCreateListViewItem

Создаёт пункт в ListView.

GUICtrlCreateListViewItem ( "text", listviewID )

Параметры

text текст или текст делённый на колонки разделителем Opt("GUIDataSeparatorChar").
listviewID идентификатор ListView, в который будет добавлен пункт.

Возвращаемое значение

Успех:Возвращает идентификатор (controlID) нового элемента.
Ошибка:Возвращает 0.

Примечания

Эта функция создает индивидуальные элементы ListView, которые могут быть выбраны. Пункты ListView являются обычными элементами и могут быть установлены с помощью GUICtrlSetData.
Пункты ListView могут быть удалены, как любой другой элемент с помощью GUICtrlDelete.
Пункты ListView можно перетащить и бросить в элементы Edit или Input со статусом $GUI_DROPACCEPTED.
Смотрите GUICtrlCreateListView об изменении размера колонок.

Специальный флаг $GUI_BKCOLOR_LV_ALTERNATE может быть использован с элементом Listview чтобы дать альтернативный фон пунктам ListviewItems.
Нечётные строки получите установкой цвета GUICtrlSetBkColor для Listview.
Чётные строки получите установкой цвета GUICtrlSetBkColor для ListviewItem.

См. также

GUICtrlCreateListView, GUICtrlSetData, GUICtrlSetState, GUICtrlDelete, GUIGetMsg, GUICtrlRead, GUIDataSeparatorChar (Опция)

Пример

#include <ListViewConstants.au3>
#include <GUIConstantsEx.au3>

Local $hGUI, $ListView, $button, $item1, $item2, $item3, $item4, $item5, $msg, $Count, $Sort

$hGUI = GUICreate("ListView", 240, 260, 150, 250)
GUISetBkColor(0xECE9D8) ; устанавливает цвет фона Gui

$ListView = GUICtrlCreateListView("Колонка1|кол2|кол3  ", 10, 10, 220, 150);,$LVS_SORTDESCENDING)
$item1 = GUICtrlCreateListViewItem("пункт2|кол22|кол23", $ListView)
$item2 = GUICtrlCreateListViewItem("пункт8|кол12|кол13", $ListView)
$item3 = GUICtrlCreateListViewItem("пункт5|кол32|кол33", $ListView)
$item4 = GUICtrlCreateListViewItem("пункт9|кол42|кол43", $ListView)
$item5 = GUICtrlCreateListViewItem("пункт3|кол52|кол53", $ListView)

$button = GUICtrlCreateButton("Стиль CheckBox и сетка", 45, 170, 150, 25)
$Sort = GUICtrlCreateButton("Сортировать", 75, 200, 90, 25)
$Count = GUICtrlCreateButton("Количество пунктов", 55, 230, 130, 25)

GUISetState()

GUICtrlSetData($item2, "ПУНКТ1")
GUICtrlSetData($item3, "||КОЛ33")
GUICtrlDelete($item1)

Do
    $msg = GUIGetMsg()

    Select ; рекомендуется использовать Switch вместо Select
        Case $msg = $button
            ; изменяет стиль, только с префиксом EX_ (расширенный)
            GUICtrlSendMsg($ListView, $LVM_SETEXTENDEDLISTVIEWSTYLE, 0, $LVS_EX_CHECKBOXES + $LVS_EX_GRIDLINES)
        Case $msg = $Count
            MsgBox(0, 'Количество пунктов', GUICtrlSendMsg($ListView, $LVM_GETITEMCOUNT, 0, 0), 0, $hGUI)
        Case $msg = $Sort
            GUICtrlSendMsg($ListView, $LVM_SORTITEMS, 0, 0)
        Case $msg = $ListView
            MsgBox(4096, "ListView", "колонка=" & GUICtrlGetState($ListView), 2, $hGUI)
    EndSelect
Until $msg = $GUI_EVENT_CLOSE