↑  ←  Описание функции


GUICtrlCreateLabel

Создаёт Label (текстовую строку) в GUI.

GUICtrlCreateLabel ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1 ]]]] )

Параметры

text Текст элемента
left Координата левого края. Если -1 - тогда координата в соответствии с GUICoordMode.
top Координата верхнего края. Если -1 - тогда координата в соответствии с GUICoordMode.
width [необязательный] Ширина элемента (по умолчанию устанавливается по длине текста).
height [необязательный] Высота элемента (по умолчанию устанавливается по высоте текста).
style [необязательный] Стиль элемента. Смотрите Стили элементов GUI в приложении.
-1 - по умолчанию : отсутствует.
принудительный стиль : $SS_NOTIFY, $SS_LEFT
exStyle [необязательный] Расширенный стиль элемента. Смотрите таблицу расширенных стилей.

Возвращаемое значение

Успех:Возвращает идентификатор (controlID) нового элемента.
Ошибка:Возвращает 0.

Примечания

Чтобы установить или изменить параметры элемента смотрите GUICtrlUpdate....

Чтобы объединить стили со стилем по умолчанию используйте BitOR($GUI_SS_DEFAULT_LABEL, новый стиль,...).

Чтобы использовать параметры, указанные выше, вы должны включить в ваш скрипт #include <StaticConstants.au3>.

По умолчанию стиль изменения размеров $GUI_DOCKAUTO (размер и позиция изменяются пропорционально).

Расширенный стиль $GUI_WS_EX_PARENTDRAG может использоваться для перетаскивания окна, которое не имеет заголовка (без стиля $WS_CAPTION в GUICreate).

Для установки прозрачного фона используйте GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT).

См. также

GUICoordMode (Опция), GUICtrlUpdate..., GUIGetMsg

Пример

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

GUICreate('Стили Label', 250, 320)
GUICtrlCreateLabel('Слева', 10, 10, 150, 17, $SS_LEFT)
GUICtrlSetBkColor(-1, 0xfdffae)
GUICtrlCreateLabel('по центру', 10, 30, 150, 17, $SS_CENTER)
GUICtrlSetBkColor(-1, 0xf8ed83)
GUICtrlCreateLabel('справа', 10, 50, 150, 17, $SS_RIGHT)
GUICtrlSetBkColor(-1, 0xfdffae)
GUICtrlCreateLabel('по центру по вертикали', 10, 70, 150, 27, $SS_CENTERIMAGE)
GUICtrlSetBkColor(-1, 0xf8ed83)
GUICtrlCreateLabel('без авто переноса на новую строку', 10, 100, 150, 27, $SS_LEFTNOWORDWRAP)
GUICtrlSetBkColor(-1, 0xfdffae)
GUICtrlCreateLabel('с углублением', 10, 130, 150, 19, $SS_SUNKEN) ; тоже что $WS_EX_STATICEDGE
GUICtrlCreateLabel('с углублением 2', 10, 152, 150, 21, -1, $WS_EX_CLIENTEDGE)
GUICtrlCreateLabel('Выпуклый', 10, 176, 150, 21, -1, $WS_EX_DLGMODALFRAME)
GUICtrlCreateLabel('с границами', 10, 200, 150, 19, $WS_BORDER)
GUICtrlSetBkColor(-1, 0xfdffae)
GUICtrlCreateLabel('---', 10, 225, 150, 0, $SS_ETCHEDHORZ) ; горизонтальная линия
GUICtrlCreateLabel('|', 80, 228, 0, 14, $SS_ETCHEDVERT) ; вертикальная линия
GUICtrlCreateLabel('без текста, статичная рамка', 10, 250, 150, 19, $SS_ETCHEDFRAME)
GUICtrlCreateLabel('Статичная рамка', 12, 252, 146, 15)
GUICtrlCreateLabel('Если ширина -1, то Label по длине текста', 10, 275, -1, 17)
GUICtrlSetBkColor(-1, 0xfdffae)
GUICtrlCreateLabel('За этот Label можно тащить окно', 10, 295, -1, 17, -1, $GUI_WS_EX_PARENTDRAG)
GUICtrlSetBkColor(-1, 0xfdffae)
GUISetState()
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE